# Maintainer : manuel at endeavouros.com

pkgname=iso-create-ml
pkgver=26.6.3
pkgrel=1
pkgdesc="Create a mirrorlist for the ISO"
arch=('any')
license=('GPL3')
depends=(eos-bash-shared parallel curl reflector)
source=(
    create-ml
    create-ml.bash-completion
    create-ml-rankmirrors-arch
    create-ml.conf
    create-ml-country-mapping-arch.conf
    create-ml-active-mirrors-arch.conf
)
sha256sums=('a662d045a187902073fd30e4f19b5ae9e3b3e096fdf85222a8593300aa26c79c'
            'eb12dd481752d0d1a6d95c312c3489b5dd98a2a7baf3ab3175240d2150659418'
            'f5fb14988ee5f9e50ea87fc9d6b0e7f4ac9c3e393b21287939448b28a8f9a047'
            'a4b50820f58c4469c8daaad09f8e03a6a5e52cfc9a1516cf889d1ffb25003604'
            'a52800cf08a67ca685e0943c5e6746b984904e7176a5897813ffa2f78314c367'
            '90d3bcdef8ca89cc0bddf68340ac153edf9286901458d86fc1bc5760e442ef41')
backup=(etc/create-ml.conf)

_prepare_iso_create_ml() {
    local _markerfile=/tmp/tmp.IpJD89lkjMNB3BaY
    [ -r $_markerfile ] && return 0
    touch $_markerfile
    # echo "==> Running ${FUNCNAME[0]}." >&2

    local _program=${source[0]}
    local _cmd="$_program --update-supports"
    if pgrep assets.make >/dev/null ; then
        $_cmd 2>/dev/null
    else
        $_cmd
    fi
    return 0
}
_prepare_iso_create_ml

package() {
    local src
    for src in "${source[@]}" ; do
        src=${src##*/}
        case "$src" in
            *.bash-completion) install -Dm644 "$src"  "$pkgdir/usr/share/bash-completion/completions/${src%.bash-completion}" ;;
            *.conf)            install -Dm644 "$src"  "$pkgdir/etc/$src" ;;
            *)                 install -Dm755 "$src"  "$pkgdir/usr/bin/$src" ;;
        esac
    done
}
