# Original Maintainer: Gustau Castells <karasu@antergos.com>
# Maintainer: manuel at endeavouros.com
# Contributor: joekamprad <joekamprad@endeavouros.com>

pkgname=nvidia-inst
pkgver=26.1.1
pkgrel=1
pkgdesc="Script to install/uninstall nvidia driver packages in EndeavourOS"
url=https://github.com/endeavouros-team/PKGBUILDS/tree/master/$pkgname
_url=https://raw.githubusercontent.com/endeavouros-team/PKGBUILDS/master/$pkgname
arch=('any')
license=('GPL2')
replaces=(nvidia-installer-dkms nvidia-installer-db nvidia-installer-common)
conflicts=(nvidia-installer-common)
depends=(expac)
optdepends=(
  "linux-headers: needed by nvidia-dkms or nvidia-open-dkms"
  "linux-lts-headers: needed by nvidia-dkms or nvidia-open-dkms"
  "linux-hardened-headers: needed by nvidia-dkms or nvidia-open-dkms"
  "linux-zen-headers: needed by nvidia-dkms or nvidia-open-dkms"
  "dkms: for the dkms versions of the proprietary Nvidia drivers"
)

source=(
  $_url/nvidia-inst
  $_url/nvidia-inst.bash-completion
  # $_url/nvidia-installer-kernel-para
  # $_url/nvidia-driver-supported-branches
)
sha512sums=('6405bc3d19a4bcce887f608d3fa78e49cfb8649552b7f5f1695e019095afad49f92533f9a6a58ada9c649f9503e79eb6fb36f5e78fc8d1d3d099df372eafceda'
            'b8857ff98870ac8cff78e31c660bde3b7308752ee4e6547682340866ee59f5801f09ede41e490380a40926536f47259f5d347fd59e8e2ffa67a8cb57f07c44e6')

package() {
    local src file

    for src in "${source[@]}" ; do
        file="${src##*/}"
        case "$src" in
            *.bash-completion) install -Dm644 "$file"  "$pkgdir/usr/share/bash-completion/completions/${file%.*}" ;;
            *)                 install -Dm755 "$file"  "$pkgdir/usr/bin/$file"
        esac
    done
}
